Transferir programas a través de FTP

Los programas pueden ser transferidos fácilmente a través del FTP desde RoboDK para robots ABB.

1.Haga clic derecho en el robot en RoboDK

2.Seleccione Conectar al robot...

3.Introduzca la IP del robot

4.Introduzca la trayectoria FTP remota.           
La trayectoria completa puede ser recuperada desde el teach pendant o usando el cliente FTP FileZilla.

5.Introduzca las credenciales de FTP (anónimas por defecto)

Una vez que un programa RoboDK está listo para ser enviado al robot:

1.Haga clic derecho en un programa en RoboDK

2.Seleccione Enviar programa al robot (Ctrl+F6)    
Esto generará el programa e intentará transferirlo al controlador del robot. Una ventana aparecerá mostrando si la transferencia FTP fue exitosa o no.

Cuando los programas sean transferidos a través del FTP necesitan ser cargadas usando la programación RAPID del robot. El siguiente ejemplo se ejecutará en el programa main_RoboDK desde un módulo llamado MOD_Pick_and_place:

MODULE RoboDK_FTP_Run_Program

    ! Enter the path to a folder with write access rights. Example:

    CONST string PATH_ROBODK := "/hd0a/robot-serial-num/HOME/RoboDK";

    PERS string ftp_program_loaded := ";

    PROC Main()

        FTP_Run_Program;

    ENDPROC

    PROC FTP_Run_Program()

        var num module_id := -1;

        WHILE module_id <= 0 DO

            TPErase;

            TPReadNum module_id, "Enter the program to run. For example: to run Prog2 in Module Prog2.mod type 2.";

        ENDWHILE

        FTP_Run_Program_ID(module_id);

    ENDPROC

    PROC FTP_Run_Program_ID(num module_id)

        VAR string path_module := "";

        VAR string mod_to_unload;

        IF module_id <= 0 THEN

            RETURN;

        ENDIF       

        path_module := PATH_ROBODK + "/Prog" + NumToStr(module_id, 0) + ".mod";

        IF StrLen(ftp_program_loaded) > 0 THEN

            mod_to_unload := ftp_program_loaded;

            ftp_program_loaded := "";

            UnLoad mod_to_unload; 

        ENDIF       

        Load path_module;

        ftp_program_loaded := path_module;

        TPWrite "Starting program: " + path_module;

        ! call the main program from the module sent and loaded

        ! %"main_RoboDK"%;

        ! call the numbered program (it should have the same effect)

        %"Prog"+NumToStr(module_id,0)%;

        TPWrite "Program completed";

    ENDPROC

ENDMODULE