Передача программ по FTP

Программы для роботов ABB можно легко передавать через FTP из RoboDK:

1.Щелкните правой кнопкой мыши по роботу в RoboDK

2.Выберите «Подключиться к роботу…»

3.Введите IP-адрес робота

4.Введите удалённый путь FTP.       
Полный путь можно узнать с помощью пульта программирования или с помощью FTP-клиента FileZilla.

5.Введите учетные данные FTP (по умолчанию — анонимный доступ)

Как только программа RoboDK будет готова к отправке на робот:

1.Щелкните правой кнопкой мыши по программе в RoboDK

2.Выберите «Отправить программу на робота» (Ctrl+F6)         
В результате программа будет сгенерирована, и будет предпринята попытка её передачи на контроллер робота. Появится всплывающее окно с информацией об успешности или неудаче передачи по FTP.

Robots ABB - Изображение 4Robots ABB - Изображение 5

Когда программы передаются по FTP в режиме реального времени, их необходимо загружать с помощью языка программирования RAPID на стороне робота. В следующем примере будет запущена программа «main_RoboDK» из модуля с именем «MOD_Pick_and_place»:

MODULE RoboDK_FTP_Run_Program

    ! Enter the path to a folder with write access rights. Example:

    CONST string PATH_ROBODK := "/hd0a/robot-serial-num/HOME/RoboDK";

   

    PERS string ftp_program_loaded := "";

   

    PROC Main()

        FTP_Run_Program;

    ENDPROC

   

    PROC FTP_Run_Program()

        var num module_id := -1;

        WHILE module_id <= 0 DO

            TPErase;

            TPReadNum module_id, "Enter the program to run. For example: to run Prog2 in Module Prog2.mod type 2.";

        ENDWHILE

        FTP_Run_Program_ID(module_id);

    ENDPROC

   

    PROC FTP_Run_Program_ID(num module_id)

        VAR string path_module := "";

        VAR string mod_to_unload;

        IF module_id <= 0 THEN

            RETURN;

        ENDIF       

       

        path_module := PATH_ROBODK + "/Prog" + NumToStr(module_id, 0) + ".mod";

        IF StrLen(ftp_program_loaded) > 0 THEN

            mod_to_unload := ftp_program_loaded;

            ftp_program_loaded := "";

            UnLoad mod_to_unload; 

        ENDIF       

 

        Load path_module;

        ftp_program_loaded := path_module;

 

        TPWrite "Starting program: " + path_module;

        ! call the main program from the module sent and loaded

        ! %"main_RoboDK"%;

        ! call the numbered program (it should have the same effect)

        %"Prog"+NumToStr(module_id,0)%;

       

        TPWrite "Program completed";

    ENDPROC

ENDMODULE